@echo off
setlocal enabledelayedexpansion

set "zipfileUrl=https://github.com/brechtsanders/winlibs_mingw/releases/download/13.2.0-16.0.6-11.0.0-ucrt-r1/winlibs-x86_64-posix-seh-gcc-13.2.0-mingw-w64ucrt-11.0.0-r1.zip"
set "destinationDirectory=C:\mingw64"

if not exist "C:\" (
    echo NAPAKA: Disk C:\ ni zaznan. Nujno prosi mentorje za pomoc
    echo Instalacija neuspesna. Okno lahko sedaj zapres.
    timeout 99999
    exit
)

echo Disk C:\ zaznan

if exist "%destinationDirectory%" (
    echo Zaznana obstojeca MinGW instalacija. Koncujem.
    echo Ce imas tezave s poganjanjem programov, prosi mentorje za pomoc.
    echo Okno lahko sedaj zapres.
    timeout 99999
    exit
)

echo Ustvarjam %destinationDirectory%
mkdir %destinationDirectory%

echo:
echo:
echo:
echo:

echo Prenasam datoteke s spleta. To lahko traja nekaj minut ...

set "zipfilePath=%destinationDirectory%/downloaded.zip"
powershell -Command "Invoke-WebRequest -Uri '%zipfileUrl%' -OutFile '%zipfilePath%'"

if exist "%zipfilePath%" (
    echo Uspesno nalozeno.
) else (
    echo Napaka pri nalaganju. Nujno prosi mentorje za pomoc.
    echo Instalacija neuspesna. Okno lahko sedaj zapres.
    timeout 99999
    exit
)

echo Ekstrahiram ...

cd %destinationDirectory%
tar -xf downloaded.zip

move mingw64\bin bin
move mingw64\include include
move mingw64\lib lib
move mingw64\libexec libexec
move mingw64\share share
move mingw64\x86_64-w64-mingw32 x86_64-w64-mingw32

echo Ekstrahirano. Nastavljam PATH

set "newPath=%destinationDirectory%\bin;!PATH!"
setx PATH "!newPath!"

endlocal

echo Nalaganje uspesno. Morda bo potrebno ponovno zagnati racunalnik.
echo Okno lahko sedaj zapres.
timeout 99999
exit